AddGadgetColumn()

Syntaxe

AddGadgetColumn(#Gadget, Position, Titre$, Largeur)

Ajoute une colonne au gadget spécifié par #Gadget. La 'Position' indique le numéro de colonne où sera insérée la nouvelle colonne. La 'Largeur' indique la largeur initiale de la colonne. Les gadgets supportant cette commande sont:

- ListIconGadget()
- ExplorerListGadget()

Cette commande permet de paramétrer complètement l'affichage d'un ExplorerListGadget(), soit en retirant les colonnes standard à l'aide de RemoveGadgetColumn() et en ajoutant celles de votre choix. A noter que la colonne 'Nom des fichiers' (#PB_Explorer_Name) n'a pas à être obligatoirement en première position.
Note: Pour remettre à jour le contenu du gadget (pour rafraîchir l'affichage), il convient d'utiliser SetGadgetText(). Pour remplir une colonne personnelle (qui n'est pas parmi les colonnes supportées nativement par le gadget), utiliser SetGadgetItemText() pour chaque élément, dès qu'un évènement du type #PB_EventType_Change est détecté.
Les constantes suivantes sont disponibles à la place du titre pour créer une colonne prédéfinie (qui sera rafraîchie automatiquement par le gadget):

  #PB_Explorer_Name      : Affiche le nom du fichier (ou répertoire)
  #PB_Explorer_Size      : Affiche la taille du fichier (en Ko)
  #PB_Explorer_Type      : Affiche le type du fichier
  #PB_Explorer_Attributes: Affiche les attributs du fichier (ou répertoire)
  #PB_Explorer_Created   : Affiche la date de création du fichier (ou répertoire)
  #PB_Explorer_Modified  : Affiche la date de dernière modification du fichier (ou répertoire)
  #PB_Explorer_Accessed  : Affiche la date du dernier accès au fichier (ou répertoire)

Exemple:

  ;Liste avec icônes - Ajoute des colonnes
  If OpenWindow(0, 0, 0, 400, 150, "AddGadgetColumn", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) And CreateGadgetList(WindowID(0))
    ListIconGadget(0, 10, 10, 380, 100, "Colonne standard", 150, #PB_ListIcon_GridLines)
    ButtonGadget(1, 10, 120, 150, 20, "Ajouter une nouvelle colonne")
    index = 1     ; La "colonne standard" a déjà l'index 0
    Repeat
      Evenement = WaitWindowEvent()
      If Evenement = #PB_Event_Gadget
        If EventGadget() = 1
          AddGadgetColumn(0, index, "Colonne "+Str(index), 80)
          index + 1
        EndIf
      EndIf
    Until Evenement = #PB_Event_CloseWindow
  EndIf

OS Supportés

Tous