GetEncoderClsid()

Resultat.l = GetEncoderClsid(format.s, *Clsid.CLSID)

  Procedure.l GetEncoderClsid(format.s, *Clsid.CLSID)
     Protected number.l ; nombre d'encodeurs d'image
     Protected Size.l     ; taille du tableau image encoder  en octets
     Protected *pImageCodecInfo.ImageCodecInfo ; pointeur sur le tableau image encoder   
     Protected i.l, memory.l
   
     GdipGetImageEncodersSize(@number.l, @Size.l)
     If Size = 0
        ProcedureReturn - 1 ; échec
     EndIf
   
     memory = AllocateMemory(Size)
     If memory = #Null
        ProcedureReturn - 1 ; échec
     EndIf
   
     *pImageCodecInfo = memory
     GdipGetImageEncoders(number, Size, *pImageCodecInfo)
   
     For i = 1 To number
        If format = PeekS(@*pImageCodecInfo\MimeType, -1, #PB_Unicode)
           CopyMemory(@*pImageCodecInfo\clsid, *Clsid, SizeOf(CLSID))
           FreeMemory(memory)
           ProcedureReturn i ; succès
        EndIf
        *pImageCodecInfo + SizeOf(ImageCodecInfo)
     Next i
     FreeMemory(memory)
     ProcedureReturn - 1 ; échec
  EndProcedure

format.s
[in] Chaîne Gdi+ identifiant l'encodeur choisi. Cette chaîne appelée MimeType est différente pour chaque encodeur. Ces chaînes sont un élément de l'énumération CodecInfo\MimeType. Il est préférable d'utiliser les constantes prédéfinies pour éviter une erreur sur la chaîne (sensible à la casse).

*Clsid.CLSID
[out] Variable de type CLSID qui recevra l'identifiant de l'encodeur recherché (paramètre format).

La procédure permet de retrouver l'identifiant CLSID pour l'encodeur choisi.

La procédure retourne -1 en cas d'échec, sinon elle retourne une valeur différente.

PureBasic v4.30 bêta 4 (Windows - x86)
Testé avec Windows Vista édition familiale Premium

Les exemples suivants utilisent cette macro :

GDIplus_1_0\Image\

GdipSaveAdd

GdipSaveAddImage

GdipSaveImageToStream